Mail::DKIM::Signer - generates a DKIM signature for a message
use Mail::DKIM::Signer;
# create a signer object
my $dkim = Mail::DKIM::Signer->new(
Algorithm => "rsa-sha1",
Method => "relaxed",
Domain => "example.org",
Selector => "selector1",
KeyFile => "private.key",
);
# read an email from a file handle
$dkim->load(*STDIN);
# or read an email and pass it into the signer, one line at a time
while (<STDIN>)
{
# remove local line terminators
chomp;
s/\015$//;
# use SMTP line terminators
$dkim->PRINT("$_\015\012");
}
$dkim->CLOSE;
# what is the signature result?
my $signature = $dkim->signature;
# create a signer using the default policy
my $dkim = Mail::DKIM::Signer->new(
Algorithm => "rsa-sha1",
Method => "relaxed",
Domain => "example.org",
Selector => "selector1",
KeyFile => "private.key",
);
# create a signer using a custom policy
my $dkim = Mail::DKIM::Signer->new(
Policy => $policyfn,
);
The "default policy" is to create a DKIM signature using the specified parameters, but only if the message's sender matches the domain. The following parameters can be passed to this new() method to influence the resulting signature: Algorithm, Method, Domain, Selector, KeyFile, Identity, Timestamp.
If you want different behavior, you can provide a "signer policy" instead. A signer policy is a subroutine or class that determines signature parameters after the message's headers have been parsed. See the section /"SIGNER POLICIES" below for more information.
See Mail::DKIM::SignerPolicy for more information about policy objects.
In addition to the parameters demonstrated above, the following are recognized:
KeyFile, use Key to use an already-loaded
Mail::DKIM::PrivateKey object.
$dkim->PRINT("a line of the message\015\012");
Feeds content of the message being signed into the signer. The API is designed this way so that the entire message does NOT need to be read into memory at once.
$dkim->CLOSE;
This method finishes the canonicalization process, computes a hash, and generates a signature.
$dkim->add_signature(new Mail::DKIM::Signature(...));
Signer policies can use this method to specify complete parameters for the signature to add, including what type of signature. For more information, see Mail::DKIM::SignerPolicy.
$alg = $dkim->algorithm;
$dkim->algorithm("rsa-sha1");
$alg = $dkim->domain;
$dkim->domain("example.org");
$dkim->load($file_handle);
Reads a complete message from the designated file handle, feeding it into the signer. The message must use <CRLF> line terminators (same as the SMTP protocol).
my $headers = $dkim->headers;
This is a string containing the names of the header fields that will be signed, separated by colons.
my $key = $dkim->key; $dkim->key(Mail::DKIM::PrivateKey->load(File => "private.key"));
If you use this method to specify a private key, do not use /"key_file()".
my $filename = $dkim->key_file;
$dkim->key_file("private.key");
If you use this method to specify a private key file, do not use /"key()".
$alg = $dkim->method;
$dkim->method("relaxed");
my $address = $dkim->message_originator;
Returns the "originator address" found in the message, as a Mail::Address object. This is typically the (first) name and email address found in the From: header. If there is no From: header, then an empty Mail::Address object is returned.
To get just the email address part, do:
my $email = $dkim->message_originator->address;
See also /"message_sender()".
my $address = $dkim->message_sender;
Returns the "sender" found in the message, as a Mail::Address object. This is typically the (first) name and email address found in the Sender: header. If there is no Sender: header, it is the first name and email address in the From: header. If neither header is present, then an empty Mail::Address object is returned.
To get just the email address part, do:
my $email = $dkim->message_sender->address;
The "sender" is the mailbox of the agent responsible for the actual transmission of the message. For example, if a secretary were to send a message for another person, the "sender" would be the secretary and the "originator" would be the actual author.
$alg = $dkim->selector;
$dkim->selector("alpha");
my $signature = $dkim->signature;
Returns the generated signature. The signature is an object of type Mail::DKIM::Signature. If multiple signatures were generated, this method returns the last one.
The signature should be prepended to the message to make the resulting message. At the very least, it should precede any headers that were signed.
my @signatures = $dkim->signatures;
Returns all generated signatures, as a list.
The new() constructor takes an optional Policy argument. This can be a Perl object or class with an apply() method, or just a simple subroutine reference. The method/subroutine will be called with the signer object as an argument. The policy is responsible for checking the message and specifying signature parameters. The policy must return a nonzero value to create the signature, otherwise no signature will be created. E.g.,
my $policyfn = sub {
my $dkim = shift;
# specify signature parameters
$dkim->algorithm("rsa-sha1");
$dkim->method("relaxed");
$dkim->domain("example.org");
$dkim->selector("mx1");
# return true value to create the signature
return 1;
};
Or the policy object can actually create the signature, using the add_signature method within the policy object. If you add a signature, you do not need to return a nonzero value. This mechanism can be utilized to create multiple signatures, or to create the older DomainKey-style signatures.
my $policyfn = sub {
my $dkim = shift;
$dkim->add_signature(
new Mail::DKIM::Signature(
Algorithm => "rsa-sha1",
Method => "relaxed",
Headers => $dkim->headers,
Domain => "example.org",
Selector => "mx1",
));
$dkim->add_signature(
new Mail::DKIM::DkSignature(
Algorithm => "rsa-sha1",
Method => "nofws",
Headers => $dkim->headers,
Domain => "example.org",
Selector => "mx1",
));
return;
};
If no policy is specified, the default policy is used. The default policy signs every message using the domain, algorithm, method, and selector specified in the new() constructor.
Jason Long, <jlong@messiah.edu>
Copyright (C) 2006-2007 by Messiah College
This library is free software; you can redistribute it and/or modify it under the same terms as Perl itself, either Perl version 5.8.6 or, at your option, any later version of Perl 5 you may have available.